Archive for the Category » Flash «

OpenFrameworks looking good

Saturday, September 04th, 2010 | Author: dehash

OpenFrameworks is a C++ toolkit designed for creative coding. The Code::Blocks IDE works in a familiar way and the two combine well.

Did a quick port of an old Yugo Flash4 example to AS3 and then to OpenFrameworks C++ to try it out. Very impressed with the toolkit and IDE - if you know some AS3 and some programming you will certainly have a head start. Definitely going to experiment some more with it.

The swf movie is here and the port is below:

PLAIN TEXT

C++:

#include "testApp.h"
//--------------------------------------------------------------
void testApp::setup(){
ofSetFrameRate(50);
i =0;
a = 5;
b = 1.66;
k = 20;
for(i=0; i<NBALLS; i++) {
ball = &ballArray[i];
ball->x = 200+(i*k);
ball->y = 400;
}
for(i=0; i<NBALLS; i++) {
ball = &ballArray[i];
ball->x_value = ball->x;
ball->y_value = ball->y;
ball->vx = 0;
ball->vy = 0;
}
}
//--------------------------------------------------------------
void testApp::update(){
for(i=1; i<NBALLS; i++) {
ball = &ballArray[i];
prevBall = &ballArray[(i-1)];
ball->vx = (ball->vx + ( prevBall->x_value + k - ball->x_value) /a) /b;
ball->vy = (ball->vy + ( prevBall->y_value - ball->y_value) /a) /b;
ball->x_value += ball->vx;
ball->y_value += ball->vy;
}
ballArray[0].x_value = ballArray[0].x = mouseX;
ballArray[0].y_value = ballArray[0].y = mouseY;
for(i=0; i<NBALLS; i++) {
ball = &ballArray[i];
ball->x = ball->x_value;
ball->y = ball->y_value;
}
}
//--------------------------------------------------------------
void testApp::draw(){
for(int i=0; i<NBALLS; i++) {
ball = &ballArray[i];
ball->draw();
}
}

Category: Code Examples, Flash, OpenFrameworks | Leave a Comment

Updated Flash AS3 RobotLegs YouTube code

Friday, August 20th, 2010 | Author: dehash

Added a GUI and a search facility to the previous example. The demo movie is here and the source code is here . Still needs some work to improve the GUI and performance which will be added some time.

Category: Code Examples, Flash, RobotLegs, YouTube API | Leave a Comment

Flash AS3 RobotLegs YouTube example

Monday, August 09th, 2010 | Author: dehash

Was asked about an updated Flash YouTube example as the previous ones were quite old and Flex based. So here is a work in progress which I will update later. Still need to add a GUI and a search facility but this is the basic version for now. It uses MVCS in RobotLegs and MinimalComps to interface with YouTube. The demo movie is here and the source code is here and the demo search was Ronettes...
Some ideas used in the code were taken from three excellent articles here and here and here

Category: Code Examples, Flash, RobotLegs, YouTube API | Leave a Comment

AS3 Signals Bubbling note

Sunday, March 07th, 2010 | Author: dehash

Working with this now and just a note that it looks like a way to bubble Signals from a nested display class is as follows:

public var deluxeSignal:DeluxeSignal = new DeluxeSignal(this);
...
deluxeSignal.dispatch(new GenericEvent(true));

and the listening class further up the display list implements IBubbleEventHandler and requires the following method:

public function onEventBubbled(e:IEvent):void { trace(e +"-"+ e.target +"-"+ e.currentTarget +"-"+ e.signal); }
- - -
Added a quick example below with source code using the current signals release unedited
here

PS there is an excellent Signals video tutorial here

- - -
Update: Added a new version of the simple example that works with the latest Signals release (0.7). The onEventBubbled method now has a boolean return value to determine whether to continue bubbling or stop.
The new example code can be downloaded here

- - -

Some ideas on passing parameters:
var deluxeSignal:DeluxeSignal = new DeluxeSignal(this);
deluxeSignal.dispatch(new GenericEvent(true));
Here you are passing "this", ie the sending instance, as the GenericEvent event target so that it is available as the event.target within onEventBubbled(event:IEvent).

Alternately pass in a Value Object (VO) instead of "this" to pass more precise and data typed parameters (you would need to give it a "parent" property) or another option is to extend GenericEvent and give it some custom properties which can be read within onEventBubbled.

Category: Code Examples, Flash | 14 Comments

Quick test of FCSS

Sunday, February 14th, 2010 | Author: dehash

Spent an hour testing the cool Flash AS3 FCSS library. Seems fine to set any public property so it can trigger tweens, image loads, filters etc as in this example
There is a good FCSS video tutorial here

Trees image from here released under CC license

Code below all in one file for now as it was just a quick test. Aside from FCSS it also uses three other AS3 libraries - Tweener and MinimalComps and BumpSlide

You can view the swf here

PLAIN TEXT

Actionscript:

/**
* v0.1 code by dehash.com 2010
* Quick Test of FCSS
* Released as open source under the BSD License
* http://www.opensource.org/licenses/bsd-license.php
*/
package {
// http://code.google.com/p/minimalcomps/
import com.bit101.components.*;
// http://github.com/theflashbum/fcss
import com.flashartofwar.fcss.applicators.StyleApplicator;
import com.flashartofwar.fcss.managers.SingletonManager;
import com.flashartofwar.fcss.styles.IStyle;
import com.flashartofwar.fcss.stylesheets.*;
import flash.display.Sprite;
import flash.events.Event;
import flash.events.MouseEvent;
// trees image from http://www.flickr.com/photos/cybot586/4356730349/
public class Main extends Sprite
{
private var css:XML = <css><![CDATA[
#boxStyle {
x: 50;
y: 10;
alpha: 0.95;
width: 300;
height: 250;
color: 0x1C2331;
tweenYto: 333;
dropShadowDistance: 20;
loadImage: 4356730349_2cfcbdff4d.jpg;
}
]]>
</css>;
private var styleSheetCollection:IStyleSheetCollection =
SingletonManager.getClassReference(StyleSheetCollection) as IStyleSheetCollection;
private var txt:Text;
private var box:BoxExtended;
public function Main():void
{
if (stage) init();
else addEventListener(Event.ADDED_TO_STAGE, init);
}
private function init(e:Event = null):void
{
removeEventListener(Event.ADDED_TO_STAGE, init);
// entry point
addControls();
addBox();
}
private function addControls():void {
var window:Window = new Window(this, 400, 50, "Box CSS Window");
window.width = 320;
window.height = 460;
var vBox:VBox = new VBox(window.content);
txt = new Text(vBox, 10, 20);
txt.text = css.toString();
txt.width = 300;
txt.height = 400;
new PushButton(vBox, 180 , 0, "Apply CSS to Box", parseButtonHandler);
}
private function parseButtonHandler(e:MouseEvent):void {
var styleSheet:IStyleSheet = new FStyleSheet( );
styleSheet.parseCSS(txt.text.toString());
styleSheetCollection.removeStyleSheet("boxStyleSheet");
styleSheetCollection.addStyleSheet(styleSheet, "boxStyleSheet");
var boxStyle:IStyle = styleSheetCollection.getStyle("#boxStyle");
var styleApplicator:StyleApplicator = new StyleApplicator();
styleApplicator.applyStyle(box,boxStyle);
}
private function addBox():void {
box = new BoxExtended();
addChild(box);
}
}
}
// http://code.google.com/p/tweener/
import caurina.transitions.Tweener;
import flash.filters.DropShadowFilter;
// http://code.google.com/p/bumpslide/
import com.bumpslide.events.UIEvent;
import com.bumpslide.ui.Box;
import com.bumpslide.ui.Image;
class BoxExtended extends Box {
private var image:Image = new Image(null, Image.SCALE_CROP, -1, -1, imageLoaded);
private var _tweenYto:Number;
private var _loadImage:String;
private var _dropShadowDistance:Number;
public function BoxExtended() {
super(0xccccff,100,100,20,20);
}
public function set tweenYto(value:Number):void {
_tweenYto = value;
Tweener.addTween(this, { y:_tweenYto, time:2.5, delay:0.5, transition:"easeInOutExpo" } );
}
public function set loadImage(value:String):void {
_loadImage = "/demoimages/"+ value.split("/").pop();
if (_loadImage == "null") {
tileBitmap = null;
}else {
image.url = _loadImage;
}
}
public function set dropShadowDistance(value:Number):void {
_dropShadowDistance = value;
filters = [new DropShadowFilter(_dropShadowDistance)];
}
private function imageLoaded(e:UIEvent):void {
tileBitmap = image.imageBitmap.bitmapData;
}
}

Category: Code Examples, Flash | 3 Comments

Flash 10 3D example

Wednesday, December 23rd, 2009 | Author: dehash

3D Flash Player 10 example and code using PaperSprite and the new built in 3D instead of PaperVision. The output is similar to similar to the InteractivePlanesBoard example and some of it is loosely based on this example code too.
view swf here

PLAIN TEXT

Actionscript:

/**
* v0.1 code by dehash.com 2009
* Flash Player 10 swf using PaperSprite similar to InteractivePlanesBoard
* http://www.dehash.com/?page_id=219 only using FP10 3D rather than PV3D
* code loosely based on example at :
* http://blog.soulwire.co.uk/code/open-source/two-sided-planes-in-flash-player-10
* Released as open source under the BSD License
* http://www.opensource.org/licenses/bsd-license.php
*/
package {
import flash.events.Event;
import flash.events.MouseEvent;
import flash.display.Sprite;
//http://blog.soulwire.co.uk/code/open-source/two-sided-planes-in-flash-player-10
import soulwire.display.PaperSprite;
// http://code.google.com/p/tweener/
import caurina.transitions.Tweener;
[SWF(width="800", height="600", backgroundColor="0xFFFFFF")]
public class InteractivePlanesBoard10Multi2CleanedUp extends Sprite {
private const NUM_OBJECTS:uint = 4;
[Embed(source='add.png')]
private var pic:Class;
private var size:uint = 100;
private var cnt:uint = 0;
private var holder:PaperSprite;
public function InteractivePlanesBoard10Multi2CleanedUp() {
holder = new PaperSprite();
addChild(holder);
holder.x = stage.stageWidth / 2;
holder.y = stage.stageHeight / 2;
var xOffset:Number = (NUM_OBJECTS * size) / 2;
var yOffset:Number = (NUM_OBJECTS * size) / 2;
for (var i:int = 0; i <NUM_OBJECTS; i++) {
for (var j:int = 0; j <NUM_OBJECTS; j++) {
var paperSprite:PaperSprite = new PaperSprite();
paperSprite = new PaperSprite();
paperSprite.x = -xOffset + (i * size * 1.2);
paperSprite.y = -yOffset + (j * size * 1.2);
if(cnt%5==0){
paperSprite.front = createPicSprite();
}else {
paperSprite.front = createSprite();
}
paperSprite.back = createSprite()
paperSprite.rotationY = 0;
holder.addChild(paperSprite );
paperSprite.addEventListener(MouseEvent.MOUSE_OVER, planePressedHandler, false, 0, true);
cnt++;
}
}
addEventListener ( Event.ENTER_FRAME, spin );
}
private function createSprite ():Sprite {
var sp:Sprite = new Sprite();
sp.graphics.beginFill ( Math.random() * 0xffffff );
sp.graphics.drawRect ( -size / 2, -size / 2, size, size);
sp.graphics.endFill ();
return sp;
}
public function createPicSprite():Sprite {
var sp:Sprite = new Sprite();
var b:*= new pic();
b.width = b.height = size;
sp.addChild(b);
return sp;
}
private function spin ( event:Event ):void {
var mX:Number = ((mouseX / stage.stageWidth) - 0.5) * 360;
var mY:Number = ((mouseY / stage.stageHeight) - 0.5) * 360;
holder.rotationY += (mX - holder.rotationY) / 140;
holder.rotationX += (mY - holder.rotationX) / 140;
}
public function planePressedHandler(e:MouseEvent):void {
if (!Tweener.isTweening(e.currentTarget)) {
Tweener.addTween(e.currentTarget, { time:2, delay:0, transition:'easeinoutback', rotationY: e.currentTarget.rotationY + 180 } );
}
}
}
}

Category: Code Examples, Flash | Leave a Comment

Quick Image Viewer

Thursday, November 26th, 2009 | Author: dehash

Made a quick image displayer with zoom and pan in just a few lines of code using BumpSlide and MinimalComps which can be viewed here. The main source code is below and the image is The Starry Night by Van Gogh from here

PLAIN TEXT

Actionscript:

/**
* v0.1 code by dehash.com 2009
* based on example code at :
* http://bumpslide.googlecode.com/svn/trunk/as3/examples/zoom/ZoomDemo_01.as
* Released as open source under the BSD License
* http://www.opensource.org/licenses/bsd-license.php
*/
package {
import com.bit101.components.HBox;
import com.bit101.components.HSlider;
import com.bit101.components.Label;
import com.bit101.components.PushButton;
import com.bumpslide.ui.Applet;
import com.bumpslide.ui.ZoomPanel;
import net.stevensacks.utils.Web;
import flash.display.Bitmap;
import flash.display.Loader;
import flash.events.Event;
import flash.events.MouseEvent;
import flash.net.URLRequest;
public class ImageDisplayer extends Applet {
static private const CONTENT_URL:String = "starrynight1280.jpg";
private var zoomPanel:ZoomPanel;
private var image:Loader;
private var myZoomSlider:HSlider;
private var controls:HBox;
private var credits:HBox;
private var offset:uint = 50;
private var label:Label;
override protected function addChildren():void {
// load image with smoothing not applied
image = new Loader();
image.contentLoaderInfo.addEventListener(Event.INIT, function(e:Event):void {
(image.content as Bitmap).smoothing = false;
});
image.load(new URLRequest(CONTENT_URL));
// create zoom panel with image as content
zoomPanel = new ZoomPanel();
zoomPanel.content = image;
addChild(zoomPanel);
// create HBox to hold controls
controls = new HBox(this);
// create controls
new PushButton(controls, 0, 0, "Home", function():void {
zoomPanel.panTo(0, 0);
});
new PushButton(controls, 0, 0, "<<--", function():void {
zoomPanel.panLeft();
});
new PushButton(controls, 0, 0, "-->>", function():void {
zoomPanel.panRight();
});
new PushButton(controls, 0, 0, "/\\", function():void {
zoomPanel.panUp();
});
new PushButton(controls, 0, 0, "\\/", function():void {
zoomPanel.panDown();
});
myZoomSlider = new HSlider(controls, 0, 5, doZoom);
myZoomSlider.tick = 0.25;
myZoomSlider.minimum = 0.25;
myZoomSlider.maximum = 7;
myZoomSlider.value = 1;
addChild(controls);
zoomPanel.dragZoomControl.minZoom = .25;
zoomPanel.dragZoomControl.maxZoom = 7;
zoomPanel.zoomContent.cacheAsBitmap = true;
// create HBox to hold credits
credits = new HBox(this);
// create credits
var labelText:String = "Van Gogh - Starry Night - 1889 -";
labelText += "(source http://www.flickr.com/photos/financialaidpodcast/3956763480/)";
label = new Label(credits, 0, 0, labelText);
new PushButton(credits, 0, 0, "Image Source", getSource);
}
private function getSource(e:MouseEvent):void {
var link:String = "http://www.flickr.com/photos/financialaidpodcast/3956763480/";
Web.getURL(link, "_blank");
}
private function doZoom(event:Event):void {
zoomPanel.zoom = myZoomSlider.value;
}
/**
* Applets are resized when stage size changes, so re-center content during redraw
*/
override protected function draw():void {
zoomPanel.move(offset, offset);
zoomPanel.setSize(width * .85, height * .85);
controls.x = offset;
controls.y = offset / 2;
credits.x = offset;
credits.y = height * .95;
}
}
}

Category: Code Examples, Flash | One Comment

Archive for the Category » Flash «

OpenFrameworks looking good

Updated Flash AS3 RobotLegs YouTube code

Flash AS3 RobotLegs YouTube example

AS3 Signals Bubbling note

Quick test of FCSS

Flash 10 3D example

Quick Image Viewer

Categories

Archive

Flash

Meta