dehash »  AS3 Papervision3D GreatWhite example code «

Some AS3 code examples that use Papervision3D GreatWhite from SVN. Made with FlashDevelop and Flex3 SDK but as they are pure AS3 examples they should work mostly the same in Flash 9 too. Some examples are clean and basic but others are less so and some are just ideas for things to explore later when more examples are added. Will try to put build/revision number in each post but note when using SVN it is inevitable that if some time has passed parts of these they may not work without tweaking in later builds. The source code text is released as open source under the BSD License which is a very open license with few restrictions. Any external media used however (bitmaps, flv, sound etc) is not covered by this license. If you notice mistakes please email dehash_at_gmail_dot_com.

 

Title: Rotation Demo

Rotation Demo example using BasicView - revision 677 - also uses minimalcomps

PLAIN TEXT
Actionscript:
  1. /**
  2. * v0.1 code by dehash.com 2008
  3. * Released as open source under the BSD License
  4. * http://www.opensource.org/licenses/bsd-license.php
  5. */
  6. package com.dehash.pv3d.examples.interactivity {
  7. import org.papervision3d.view.BasicView;
  8. import org.papervision3d.materials.ColorMaterial;
  9. import org.papervision3d.objects.primitives.Plane;
  10. import flash.display.BlendMode;
  11. import flash.display.MovieClip;
  12. import flash.events.Event;
  13. // http://code.google.com/p/minimalcomps/
  14. import com.bit101.components.Knob;
  15.  
  16. [SWF(width="800", height="600", backgroundColor="0x333333")]
  17.  
  18. public class RotationDemo extends BasicView
  19. {
  20. private var plane:Plane;
  21.  
  22. public function RotationDemo(viewportWidth:Number = 800, viewportHeight:Number = 600,
  23. scaleToStage:Boolean=true, interactive:Boolean=false, cameraType:String="CAMERA3D")
  24. {
  25. super(viewportWidth, viewportHeight, scaleToStage, interactive, cameraType);
  26.  
  27. var mc:MovieClip = new MovieClip();
  28. var dial:Knob;
  29.  
  30. dial = new Knob(null, 0, 0, "rotationX", dialChangeHandler);
  31. dial.maximum = 360;
  32. mc.addChild( dial );
  33.  
  34. dial = new Knob(null, 100, 0, "rotationY", dialChangeHandler);
  35. dial.maximum = 360;
  36. mc.addChild( dial );
  37.  
  38. dial = new Knob(null, 200, 0, "rotationZ", dialChangeHandler);
  39. dial.maximum = 360;
  40. mc.addChild( dial );
  41.  
  42. mc.scaleX = mc.scaleY = 2;
  43. mc.x = (stage.stageWidth/2)-(mc.width/2) + 65;
  44. mc.y = 100;
  45. mc.blendMode = BlendMode.INVERT
  46. addChild(mc);
  47.  
  48. var mat:ColorMaterial = new ColorMaterial();
  49. mat.doubleSided = true;
  50. plane = new Plane(mat);
  51. plane.y -= 250;
  52. scene.addChild(plane);
  53.  
  54. renderer.renderScene(scene, camera, viewport);
  55. this.startRendering();
  56. }
  57.  
  58. private function dialChangeHandler(event:Event):void {
  59. plane[event.target.label] = int(event.target.value);
  60. }
  61.  
  62. }
  63. }