dehash »  AS3 Papervision3D GreatWhite example code «

Some AS3 code examples that use Papervision3D GreatWhite from SVN. Made with FlashDevelop and Flex3 SDK but as they are pure AS3 examples they should work mostly the same in Flash 9 too. Some examples are clean and basic but others are less so and some are just ideas for things to explore later when more examples are added. Will try to put build/revision number in each post but note when using SVN it is inevitable that if some time has passed parts of these they may not work without tweaking in later builds. The source code text is released as open source under the BSD License which is a very open license with few restrictions. Any external media used however (bitmaps, flv, sound etc) is not covered by this license. If you notice mistakes please email dehash_at_gmail_dot_com.

 

Title: Torus Tweener

Tweening to position of planes set using vertices of a Torus. Uses BasicView - revision 702 - also uses Tweener and Torus - idea of tweening between vertices positions of different objects came from a mrdoob example.

PLAIN TEXT
Actionscript:
  1. /**
  2. * v0.1 code by dehash.com 2008
  3. * Released as open source under the BSD License
  4. * http://www.opensource.org/licenses/bsd-license.php
  5. */
  6.  
  7. package com.dehash.pv3d.examples.positioning {
  8. import org.papervision3d.objects.DisplayObject3D;
  9. import org.papervision3d.objects.primitives.Plane;
  10. import org.papervision3d.materials.BitmapMaterial;
  11. import org.papervision3d.view.BasicView;
  12. import flash.display.Bitmap;
  13. import flash.events.Event;
  14. // from http://code.google.com/p/tweener/
  15. import caurina.transitions.Tweener;
  16. // from http://www.topflashers.com/torus/src/pv3d.torus.zip
  17. import com.topflashers.ext.pv3d.objects.primitives.Torus;
  18.  
  19. [SWF(width="800", height="600", backgroundColor="0x000000")]
  20.  
  21. public class TorusTweener extends BasicView {
  22. [Embed(source = '../assets/sphere.png')]
  23. private var SphereImage:Class;
  24. private var world:DisplayObject3D;
  25.  
  26. public function TorusTweener(viewportWidth:Number = 800,
  27. viewportHeight:Number = 600, scaleToStage:Boolean=true,
  28. interactive:Boolean=false, cameraType:String="CAMERA3D") {
  29. super(viewportWidth, viewportHeight, scaleToStage,
  30. interactive, cameraType);
  31.  
  32. world = new DisplayObject3D();
  33. camera.target = world;
  34.  
  35. var bitmapMaterial:BitmapMaterial =
  36. new BitmapMaterial(Bitmap(new SphereImage()).bitmapData);
  37. bitmapMaterial.doubleSided = true;
  38.  
  39. var t:Torus = new Torus(null, 450, 250, 12, 12);
  40. var p:Plane = new Plane(null, 700, 10, 14, 14);
  41.  
  42. for ( var i:int = 0; i <t.geometry.vertices.length; i++) {
  43. var plane:Plane = new Plane( bitmapMaterial, 50, 50 );
  44. plane.lookAt(camera);
  45. plane.x = p.geometry.vertices[i].x;
  46. plane.y = p.geometry.vertices[i].y;
  47. plane.z = p.geometry.vertices[i].z;
  48.  
  49. Tweener.addTween(plane, {
  50. x: t.geometry.vertices[i].x,
  51. y: t.geometry.vertices[i].y,
  52. z: t.geometry.vertices[i].z,
  53. rotationX: 360*6,
  54. rotationY: 360*6,
  55. rotationZ: 360*6,
  56. time: 2*((i + 1)/10),
  57. delay: 3,
  58. transition: "easeInOutElastic"
  59. });
  60.  
  61. world.addChild(plane);
  62. }
  63.  
  64. scene.addChild(world);
  65. startRendering();
  66. }
  67.  
  68. protected override function onRenderTick(event:Event = null):void {
  69. camera.x -= (camera.x - Math.sin(mouseX*0.01)*1200) /8;
  70. camera.z -= (camera.z - Math.cos(mouseX*0.01)*1200) /8;
  71. camera.y -= (camera.y - viewport.containerSprite.mouseY * 5) / 8;
  72. renderer.renderScene(scene, camera, viewport);
  73. }
  74.  
  75. }
  76. }